dnl Establim el nom del paquet, la versió i l'email de contacte
AC_INIT(eiciel, 0.9.6.1, rofi@ya.com)

dnl On estem ?
AC_CANONICAL_BUILD
AC_CANONICAL_HOST
AC_CANONICAL_TARGET

dnl Establim com a prerequisit Autoconf 2.59
AC_PREREQ(2.57)

dnl Inicialitzem Automake
AM_INIT_AUTOMAKE([dist-bzip2])

dnl Volem suport de GETTEXT
AM_GNU_GETTEXT([external])
AM_GNU_GETTEXT_VERSION([0.15])

dnl Nomes serveix per veure si hi ha el codi
AC_CONFIG_SRCDIR(src/eiciel_standalone.cpp)

dnl Establim el config header
AC_CONFIG_HEADER(config.hpp)

dnl Volem que les proves es facin amb C++
AC_LANG(C++)

dnl Comprovem si hi ha el programa install
AC_PROG_INSTALL

dnl Comprovem si hi ha un preprocessador de C/C++
AC_PROG_CPP

dnl Comprovem si hi ha un compilador de C++
AC_PROG_CXX

dnl Hem de crear una llibreria dinamica
AC_PROG_LIBTOOL

dnl Comprovem si hi ha la llibreria gtkmm-2.0
PKG_CHECK_MODULES(GTKMM, gtkmm-2.4 >= 2.4.0 libgnome-2.0 >= 2.10.0 libgnomeui-2.0 >= 2.10.0 gnome-vfs-2.0 >= 2.10.0 libnautilus-extension >= 2.10.0)

AC_MSG_CHECKING([for nautilus extensions directory])

AC_ARG_WITH(nautilus-extensions-dir, 
AC_HELP_STRING([--with-nautilus-extensions-dir=DIR], [Directory where nautilus extensions have to be installed (usually /usr/lib/nautilus/extensions-1.0)])
, 
[
if test x$withval = xyes -o x$withval = xno;
then
   AC_MSG_ERROR([If you specify --with-nautilus-extensions-dir you must set the directory. E.g.: --with-nautilus-extensions-dir=/usr/lib/nautilus/extensions-1.0])
else 
 AC_SUBST(NAUTILUS_EXTENSIONS_DIR, [$withval])
 AC_MSG_RESULT([$withval])
fi
]
,
[dnl La resta de distribucions de GNU/Linux
  extensiondir=`pkg-config --variable=extensiondir libnautilus-extension`;
  if test -n "$extensiondir" ;
  then
     AC_SUBST(NAUTILUS_EXTENSIONS_DIR, [$extensiondir])
	 AC_MSG_RESULT(${NAUTILUS_EXTENSIONS_DIR})
  else
   	AC_MSG_ERROR([I need pkg-config in order to determine where to install nautilus extensions. You may want to set --with-nautilus-extensions-dir=DIR])
  fi
]
)

enable_eua=no
AC_MSG_CHECKING([for extended user attributes support])
AC_ARG_ENABLE(user-attributes,
AC_HELP_STRING([--enable-user-attributes], [Enables support for extended user attributes. This is GNU/Linux specific.]),
[
if test x$enableval = xyes -o x$enableval = x;
then
   AC_MSG_RESULT([yes])
   enable_eua=yes
else
  if test x$enableval = xno;
  then
    enable_eua=no
    AC_MSG_RESULT([no])
  else
    AC_MSG_ERROR([This option can only be given 'yes' or 'no' values])
  fi
fi
]
,
[
 case $target_os in
     linux*)
	   enable_eua=yes
       AC_MSG_RESULT([yes, since we are in GNU/Linux])
	   ;;
	 *)
	   enable_eua=no
	   AC_MSG_RESULT([no, this does not seem to be GNU/Linux])
	 ;;
 esac
]
)

if test x$enable_eua = xyes;
then
    AC_CHECK_HEADERS([attr/xattr.h], [], AC_MSG_ERROR([This header is mandatory for extended user attributes support]), [])
    AC_DEFINE([ENABLE_USER_XATTR], [1], [Enables user extended attributes support])
fi
AM_CONDITIONAL(ENABLE_USER_XATTR, test x$enable_eua = xyes)

dnl Comprovem els headers
acl_headers=0

AC_CHECK_HEADERS([sys/acl.h],
[
acl_headers=1
], [], [])

AC_CHECK_HEADERS([acl/libacl.h],
[
acl_headers=1
], [], [])

if test x$acl_headers = x0;
then
  AC_MSG_ERROR([No suitable headers for ACL support have been found])
fi

dnl Per a FreeBSD
AC_CHECK_FUNC([acl_get_perm_np], 
 [AC_DEFINE([HAVE_ACL_GET_PERM_NP], [], [acl_get_perm_np is available])]
[])

AC_SUBST(llibreria_acl, [])
	
dnl Comprovem si hi ha la llibreria d'ACL
AC_CHECK_LIB(acl, acl_get_perm, 
 [
   AC_DEFINE([HAVE_ACL_GET_PERM], [], [acl_get_perm is available])
   AC_SUBST(llibreria_acl, [-lacl])
 ],)

dnl Volem que ens generi el fitxers seguents
AC_OUTPUT([Makefile
		src/Makefile
		img/Makefile
		lib/Makefile
		po/Makefile.in
		man/Makefile
		doc/Makefile
		doc/C/Makefile
		doc/C/figures/Makefile
		])