AC_INIT(isight-firmware-tools, 1.2, https://bugs.launchpad.net/isight-firmware-tools/+filebug)
AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
AM_MAINTAINER_MODE
AM_CONFIG_HEADER(config.h)
AC_CONFIG_FILES(Makefile
src/Makefile
doc/Makefile
src/isight.rules
po/Makefile.in
)
dnl DEPS
AC_PROG_CC
AM_PROG_CC_C_O
AC_CHECK_HEADERS([gcrypt.h],[],[AC_MSG_ERROR([libgcrypt not found])])
AC_CHECK_PROG(MAKEINFO,makeinfo,makeinfo)
PKG_CHECK_MODULES(IFT, [glib-2.0])
AC_SUBST(IFT_CFLAGS)
AC_SUBST(IFT_LIBS)
PKG_CHECK_MODULES(LOAD, [libusb])
AC_SUBST(LOAD_CFLAGS)
AC_SUBST(LOAD_LIBS)
PKG_CHECK_MODULES(HAL, [hal])
AC_SUBST(HAL_CFLAGS)
AC_SUBST(HAL_LIBS)
dnl whether to provide udev rules and loader
AC_ARG_ENABLE(udev,
[AC_HELP_STRING([--enable-udev],[Enable udev firmware loader])],
[if test $enableval = "yes" ; then
SUPPORT_UDEV=1
else
SUPPORT_UDEV=0
fi],
[SUPPORT_UDEV=0])
AM_CONDITIONAL(SUPPORT_UDEV, [test ${SUPPORT_UDEV} = 1])
dnl whether to provide hal callout
AC_ARG_ENABLE(hal,
[AC_HELP_STRING([--disable-hal],[Disable HAL callout])],
[if test $enableval = "yes" ; then
SUPPORT_HAL=1
else
SUPPORT_HAL=0
fi],
[SUPPORT_HAL=1])
AM_CONDITIONAL(SUPPORT_HAL, [test ${SUPPORT_HAL} = 1])
dnl GETTEXT
GETTEXT_PACKAGE=AC_PACKAGE_NAME
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [gettext package name])
PACKAGE_LOCALE_DIR="${datadir}/locale"
AC_SUBST(PACKAGE_LOCALE_DIR)
AM_GLIB_GNU_GETTEXT
IT_PROG_INTLTOOL([0.35])
dnl OUTPUT
AC_OUTPUT
yes_no () {
if test $1 = 0 ; then
echo "no";
else
echo "yes"
fi
}
echo
echo "HAL callout : " $(yes_no $SUPPORT_HAL)
echo "udev rules : " $(yes_no $SUPPORT_UDEV)
echo
if test $SUPPORT_UDEV = 1 -a $SUPPORT_HAL = 1 ; then
echo `tput smso` "/!\ WARNING: avoid installing both UDEV rules and HAL callout!" `tput rmso`;
echo
fi