Codebase list libcloudproviders / HEAD meson.build
HEAD

Tree @HEAD (Download .tar.gz)

meson.build @HEAD — raw · history · blame 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
project ('libcloudproviders', 'c',
  version: '0.3.1',
  meson_version: '>=0.42.0',
  license: 'LGPL3+',
  default_options: [
    'c_std=gnu99',
    'warning_level=2',
  ]
)

api_version = '@0@.@1@'.format(
  meson.project_version().split('.')[0],
  meson.project_version().split('.')[1])

cc = meson.get_compiler('c')

test_cflags = [
  '-Wno-unused-parameter',
  '-Wno-missing-field-initializers',
  '-Wstrict-prototypes',
  '-Wmissing-prototypes',
  '-Werror=implicit-function-declaration',
  '-Werror=pointer-arith',
  '-Werror=init-self',
  ['-Werror=format-security','-Werror=format=1'],
  '-Werror=date-time',
]
global_cflags = []
foreach cflag : test_cflags
  if cc.has_multi_arguments(cflag)
    global_cflags += cflag
  endif
endforeach
add_project_arguments(global_cflags, language: 'c')

glib_ver = '>= 2.51.2'
glib = dependency ('glib-2.0', version: glib_ver)
gio = dependency ('gio-2.0', version: glib_ver)
gio_unix = dependency ('gio-unix-2.0', version: glib_ver)

add_project_arguments(
  '-DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_52',
  '-DGLIB_VERSION_MAX_ALLOWED=GLIB_VERSION_2_52',
  language: 'c'
)

prefix = get_option ('prefix')
libdir = get_option ('libdir')
libexecdir = get_option ('libexecdir')
bindir = get_option ('bindir')
datadir = get_option ('datadir')
servicedir = join_paths (datadir, 'dbus-1', 'services')
incdir = join_paths (prefix, get_option('includedir'), 'cloudproviders')
girdir= join_paths(datadir, 'gir-1.0')
typelibdir = join_paths(libdir, 'girepository-1.0')

gnome = import('gnome')

subdir ('src')
subdir ('test')
if get_option ('enable-gtk-doc')
    subdir ('docs/reference')
endif