AC_INIT(src/hdate.h)
dnl Set release number
PACKAGE=libhdate
LIBHDATE_MAJOR_VERSION=1
LIBHDATE_MINOR_VERSION=4
LIBHDATE_MICRO_VERSION=9
VERSION=$LIBHDATE_MAJOR_VERSION.$LIBHDATE_MINOR_VERSION.$LIBHDATE_MICRO_VERSION
VERSION_INFO=$LIBHDATE_MAJOR_VERSION:$LIBHDATE_MINOR_VERSION:0
AC_SUBST(VERSION_INFO)
AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
AM_MAINTAINER_MODE
dnl Checks for programs.
AC_ISC_POSIX
AC_GNU_SOURCE
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_STDC_HEADERS
AM_PROG_LIBTOOL
AM_MAINTAINER_MODE
AC_C_CONST
AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
CFLAGS=
LIBS=-lm
dnl =======================================================================================
AC_CHECK_PROG(have_swig, "swig", yes, no)
dnl =======================================================================================
build_pascal=no
AC_CHECK_PROG(have_pascal, "fpc", yes, no)
AC_ARG_ENABLE(pascal, [ --enable-pascal build pascal binding [default=no]], build_pascal="$enableval", build_pascal=no)
if test "x$have_pascal" = "xno"; then
build_pascal=no
else
PA_VERSION=`fpc -iV`
PA_TPR=`fpc -iTP`
PA_TOS=`fpc -iTO`
PA_MODULES_PATH="/usr/lib/fpc/$PA_VERSION/units/$PA_TPR-$PA_TOS"
AC_SUBST([PA_VERSION])
AC_SUBST([PA_MODULES_PATH])
fi
AM_CONDITIONAL(WITH_PASCAL, test "x$build_pascal" = "xyes")
dnl =======================================================================================
build_python=no
AC_ARG_ENABLE(python, [ --enable-python build python binding [default=no]], build_python="$enableval", build_python=no)
AC_ARG_WITH(python-sitelib-dir, [ --with-python-sitelib-dir=PATH path to python site lib ])
AC_CHECK_PROG(have_python, "python", yes, no)
if test "x$have_python" = "xyes"; then
PY_PREFIX=`python -c 'import sys ; print sys.prefix'`
PY_VERSION=`python -c 'import sys ; print sys.version[[0:3]]'`
AC_MSG_CHECKING(for $PY_PREFIX/include/python$PY_VERSION/Python.h)
if test -f $PY_PREFIX/include/python$PY_VERSION/Python.h; then
AC_MSG_RESULT(yes)
PY_CFLAGS="-I$PY_PREFIX/include/python$PY_VERSION"
if test "x$with_python_sitelib_dir" = "x" ; then
PY_MODULES_PATH="$PY_PREFIX/lib/python$PY_VERSION/site-packages"
else
PY_MODULES_PATH=$with_python_sitelib_dir
fi
AC_SUBST([PY_VERSION])
AC_SUBST([PY_CFLAGS])
AC_SUBST([PY_MODULES_PATH])
if test "x$have_swig" = "xno"; then
build_python=no
fi
else
AC_MSG_RESULT(no)
build_python=no
fi
fi
AM_CONDITIONAL(WITH_PYTHON, test "x$build_python" = "xyes")
dnl =======================================================================================
build_perl=no
AC_ARG_ENABLE(perl, [ --enable-perl build perl binding [default=no]], build_perl="$enableval", build_perl=no)
AC_ARG_WITH(perl-sitelib-dir, [ --with-perl-sitelib-dir=PATH path to perl site lib ])
AC_CHECK_PROG(have_perl, "perl", yes, no)
if test "x$have_perl" = "xyes"; then
PE_PREFIX=`(perl -e 'use Config; print $Config{archlib};')`
AC_MSG_CHECKING(for $PE_PREFIX/CORE/perl.h)
if test -f $PE_PREFIX/CORE/perl.h; then
AC_MSG_RESULT(yes)
PE_CFLAGS="-I$PE_PREFIX/CORE "
PE_CFLAGS=$PE_CFLAGS`(perl -e 'use Config; print $Config{cppflags};')`
if test "x$with_perl_sitelib_dir" = "x" ; then
PE_MODULES_PATH=`(perl -e 'use Config; print $Config{sitelib};')`
else
PE_MODULES_PATH=$with_perl_sitelib_dir
fi
AC_SUBST([PE_CFLAGS])
AC_SUBST([PE_MODULES_PATH])
if test "x$have_swig" = "xno"; then
build_perl=no
fi
else
AC_MSG_RESULT(no)
build_perl=no
fi
fi
dnl FIXME: on fedora PE_MODULES_PATH="/usr/lib/perl5/site_perl"
AM_CONDITIONAL(WITH_PERL, test "x$build_perl" = "xyes")
dnl =======================================================================================
dnl gettext
dnl Languages which your application supports
ALL_LINGUAS="he es_MX ru fr sv"
AM_GNU_GETTEXT
AM_GNU_GETTEXT_VERSION(0.10.40)
if test "x${prefix}" = "xNONE"; then
AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${ac_default_prefix}/${DATADIRNAME}/locale")
else
AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${prefix}/${DATADIRNAME}/locale")
fi
dnl =======================================================================================
build_examples=no
AC_ARG_ENABLE(examples, [ --enable-examples build examples [default=no]], build_examples="$enableval", build_examples=no)
AM_CONDITIONAL(WITH_EXAMPLES, test "x$build_examples" = "xyes")
dnl =======================================================================================
build_hcal=yes
AC_ARG_ENABLE(hcal, [ --disable-hcal build hcal/hdate [default=yes]], build_hcal="$enableval", build_hcal=yes)
AM_CONDITIONAL(WITH_HCAL, test "x$build_hcal" = "xyes")
dnl =======================================================================================
AC_SUBST(CFLAGS)
AC_SUBST(LIBS)
dnl =======================================================================================
AC_OUTPUT([
Makefile
libhdate.spec
libhdate.pc
intl/Makefile
po/Makefile.in
src/Makefile
examples/Makefile
examples/hcal/Makefile
examples/ical/Makefile
examples/html/Makefile
examples/hebcal/Makefile
examples/bindings/Makefile
bindings/Makefile
bindings/python/Makefile
bindings/perl/Makefile
bindings/pascal/Makefile
])
dnl ===========================================================================================
echo "
$PACKAGE-$VERSION
prefix: ${prefix}
compiler: ${CC}
have swig ${have_swig}
have free pascal ${have_pascal}
have python ${have_python}
have perl ${have_perl}
build hcal ${build_hcal}
build examples ${build_examples}
build python binding ${build_python}
build perl binding ${build_perl}
puild pascal binding ${build_pascal}
perl site lib path: $PE_MODULES_PATH
python site lib path: $PY_MODULES_PATH
pascal site lib path: $PA_MODULES_PATH
"