Codebase list libsdl2-net / ae7b4b38-2e17-4a1b-97ee-f1f0d5835ba5/main sdl2_net-config.cmake.in
ae7b4b38-2e17-4a1b-97ee-f1f0d5835ba5/main

Tree @ae7b4b38-2e17-4a1b-97ee-f1f0d5835ba5/main (Download .tar.gz)

sdl2_net-config.cmake.in @ae7b4b38-2e17-4a1b-97ee-f1f0d5835ba5/main — raw · history · blame 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
# sdl2_net cmake project-config input for ./configure scripts

include(FeatureSummary)
set_package_properties(SDL2_net PROPERTIES
    URL "https://www.libsdl.org/projects/SDL_net/"
    DESCRIPTION "SDL_net is an example portable network library for use with SDL."
)

set(SDL2_net_FOUND TRUE)

get_filename_component(prefix "${CMAKE_CURRENT_LIST_DIR}/@cmake_prefix_relpath@" ABSOLUTE)
set(exec_prefix "@exec_prefix@")
set(bindir "@bindir@")
set(includedir "@includedir@")
set(libdir "@libdir@")
set(_sdl2net_extra_static_libraries "@INETLIB@;@PC_LIBS@")
string(STRIP "${_sdl2net_extra_static_libraries}" _sdl2net_extra_static_libraries)

set(_sdl2net_bindir   "${bindir}")
set(_sdl2net_libdir   "${libdir}")
set(_sdl2net_incdir   "${includedir}/SDL2")

# Convert _sdl2net_extra_static_libraries to list and keep only libraries
string(REGEX MATCHALL "(-[lm]([-a-zA-Z0-9._]+))|(-Wl,[^ ]*framework[^ ]*)" _sdl2net_extra_static_libraries "${_sdl2net_extra_static_libraries}")
string(REGEX REPLACE "^-l" "" _sdl2net_extra_static_libraries "${_sdl2net_extra_static_libraries}")
string(REGEX REPLACE ";-l" ";" _sdl2net_extra_static_libraries "${_sdl2net_extra_static_libraries}")

unset(prefix)
unset(exec_prefix)
unset(bindir)
unset(includedir)
unset(libdir)

include(CMakeFindDependencyMacro)

if(NOT TARGET SDL2_net::SDL2_net)
    add_library(SDL2_net::SDL2_net SHARED IMPORTED)
    set_target_properties(SDL2_net::SDL2_net
        PROPERTIES
            INTERFACE_INCLUDE_DIRECTORIES "${_sdl2net_incdir}"
            COMPATIBLE_INTERFACE_BOOL "SDL2_SHARED"
            INTERFACE_SDL2_SHARED "ON"
    )
    if(WIN32)
        set_target_properties(SDL2_net::SDL2_net
            PROPERTIES
                IMPORTED_LOCATION "${_sdl2net_bindir}/SDL2_net.dll"
                IMPORTED_IMPLIB "${_sdl2net_libdir}/${CMAKE_STATIC_LIBRARY_PREFIX}SDL2_net.dll${CMAKE_STATIC_LIBRARY_SUFFIX}"
        )
    else()
        set_target_properties(SDL2_net::SDL2_net
            PROPERTIES
                IMPORTED_LOCATION "${_sdl2net_libdir}/${CMAKE_SHARED_LIBRARY_PREFIX}SDL2_net${CMAKE_SHARED_LIBRARY_SUFFIX}"
        )
    endif()
endif()

if(NOT TARGET SDL2_net::SDL2_net-static)
    add_library(SDL2_net::SDL2_net-static STATIC IMPORTED)

    set_target_properties(SDL2_net::SDL2_net-static
        PROPERTIES
            INTERFACE_INCLUDE_DIRECTORIES "${_sdl2net_incdir}"
            IMPORTED_LOCATION "${_sdl2net_libdir}/${CMAKE_STATIC_LIBRARY_PREFIX}SDL2_net${CMAKE_STATIC_LIBRARY_SUFFIX}"
            INTERFACE_LINK_LIBRARIES "${_sdl2net_extra_static_libraries}"
    )
endif()

unset(_sdl2net_extra_static_libraries)
unset(_sdl2net_bindir)
unset(_sdl2net_libdir)
unset(_sdl2net_incdir)