Codebase list libvirt / debian/1.2.1-1 m4 / execinfo.m4
debian/1.2.1-1

Tree @debian/1.2.1-1 (Download .tar.gz)

execinfo.m4 @debian/1.2.1-1 — raw · history · blame 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
# Check for GNU-style execinfo.h.

dnl Copyright 2012-2014 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

AC_DEFUN([gl_EXECINFO_H],
[
  AC_CHECK_HEADERS_ONCE([execinfo.h])

  LIB_EXECINFO=''
  EXECINFO_H='execinfo.h'

  if test $ac_cv_header_execinfo_h = yes; then
    gl_saved_libs=$LIBS
      AC_SEARCH_LIBS([backtrace_symbols_fd], [execinfo],
        [test "$ac_cv_search_backtrace_symbols_fd" = "none required" ||
         LIB_EXECINFO=$ac_cv_search_backtrace_symbols_fd])
    LIBS=$gl_saved_libs
    test "$ac_cv_search_backtrace_symbols_fd" = no || EXECINFO_H=''
  fi

  if test -n "$EXECINFO_H"; then
    AC_LIBOBJ([execinfo])
  fi

  AC_SUBST([EXECINFO_H])
  AC_SUBST([LIB_EXECINFO])
  AM_CONDITIONAL([GL_GENERATE_EXECINFO_H], [test -n "$EXECINFO_H"])
])